[nix] Fix configuration

Reuse common shell for nix package. Add options for nix-way
configuration of yandex music.

Change-Id: I71a209a8ca8b5e3c5c08349b8da5ba91182a919e

nix/module.nix

@@ -0,0 +1,53 @@
+{ yandex-music-with
+, isHm ? false
+}:
+{ lib, pkgs, config, ... }:
+let
+  cfg = config.programs.yandex-music;
+
+in
+{
+  imports = [{
+    nixpkgs.overlays = [
+      (final: prev: {
+        yandex-music = yandex-music-with prev;
+      })
+    ];
+  }];
+
+  options = {
+    programs.yandex-music = {
+      enable = lib.mkEnableOption "yandex music application";
+      tray.enable = lib.mkEnableOption "tray icon for yandex music application";
+      electronArguments = lib.mkOption {
+        description = "Extra electron arguments";
+        example = "--no-sandbox --trace-warnings";
+        type = lib.types.str;
+        default = "";
+      };
+      package = lib.mkOption {
+        description = "Finalized package of yandex music application";
+        type = lib.types.package;
+        default = pkgs.yandex-music.override {
+          trayEnabled = cfg.tray.enable;
+          electronArguments = cfg.electronArguments;
+        };
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable (
+    if isHm then
+      {
+        home.packages = [
+          cfg.package
+        ];
+      }
+    else
+      {
+        environment.systemPackages = [
+          cfg.package
+        ];
+      }
+  );
+}