LimeReport/3rdparty/zint-2.4.4/backend_qt4/Zint.pro

DEFINES += NO_PNG

TEMPLATE = lib
CONFIG += dll

CONFIG(release, debug|release){
    message(Release)
    BUILD_TYPE = release
}else{
    message(Debug)
    BUILD_TYPE = debug
}

include(../../../common.pri)

macx{
    CONFIG -= dll
    CONFIG += lib_bundle
    CONFIG += plugin
}

unix{
    CONFIG += plugin
}

#VERSION = 2.4.4

INCLUDEPATH += $$PWD/../backend
DEFINES +=  _CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_WARNINGS ZINT_VERSION=\\\"$$VERSION\\\"
DEFINES += QZINT_LIBRARY
TARGET = QtZint

!contains(DEFINES, NO_PNG) {
    SOURCES += $$PWD/../backend/png.c
    LIBS += -lpng
}


win32-msvc* {
    DEFINES += _CRT_SECURE_NO_WARNINGS
    #QMAKE_CFLAGS += /TP /wd4018 /wd4244 /wd4305
    #QMAKE_CXXFLAGS += /TP /wd4018 /wd4244 /wd4305
}


INCLUDEPATH += zint zint/backend zint/backend_qt4

HEADERS += \
    $$PWD/qzint.h \
    $$PWD/qzint_global.h \
    $$PWD/../backend/aztec.h \
    $$PWD/../backend/code1.h \
    $$PWD/../backend/code49.h \
    $$PWD/../backend/common.h \
    $$PWD/../backend/composite.h \
    $$PWD/../backend/dmatrix.h \
    $$PWD/../backend/font.h \
    $$PWD/../backend/gb2312.h \
    $$PWD/../backend/gridmtx.h \
    $$PWD/../backend/gs1.h \
    $$PWD/../backend/large.h \
    $$PWD/../backend/maxicode.h \
    $$PWD/../backend/maxipng.h \
    $$PWD/../backend/ms_stdint.h \
    $$PWD/../backend/pdf417.h \
    $$PWD/../backend/qr.h \
    $$PWD/../backend/reedsol.h \
    $$PWD/../backend/rss.h \
    $$PWD/../backend/sjis.h \
    $$PWD/../backend/zint.h

SOURCES += \
    $$PWD/qzint.cpp \
    $$PWD/../backend/2of5.c \
    $$PWD/../backend/auspost.c \
    $$PWD/../backend/aztec.c \
    $$PWD/../backend/code.c \
    $$PWD/../backend/code1.c \
    $$PWD/../backend/code16k.c \
    $$PWD/../backend/code49.c \
    $$PWD/../backend/code128.c \
    $$PWD/../backend/common.c \
    $$PWD/../backend/composite.c \
    $$PWD/../backend/dllversion.c \
    $$PWD/../backend/dmatrix.c \
    $$PWD/../backend/gridmtx.c \
    $$PWD/../backend/gs1.c \
    $$PWD/../backend/imail.c \
    $$PWD/../backend/large.c \
    $$PWD/../backend/library.c \
    $$PWD/../backend/maxicode.c \
    $$PWD/../backend/medical.c \
    $$PWD/../backend/pdf417.c \
    $$PWD/../backend/plessey.c \
    $$PWD/../backend/png.c \
    $$PWD/../backend/postal.c \
    $$PWD/../backend/ps.c \
    $$PWD/../backend/qr.c \
    $$PWD/../backend/reedsol.c \
    $$PWD/../backend/render.c \
    $$PWD/../backend/rss.c \
    $$PWD/../backend/svg.c \
    $$PWD/../backend/telepen.c \
    $$PWD/../backend/upcean.c


unix {
    UNIX_DIR      = $${OUT_PWD}/unix
    MOC_DIR        = $${UNIX_DIR}/moc/$${BUILD_TYPE}
    UI_DIR         = $${UNIX_DIR}/ui/$${BUILD_TYPE}
    UI_HEADERS_DIR = $${UNIX_DIR}/ui/$${BUILD_TYPE}
    UI_SOURCES_DIR = $${UNIX_DIR}/ui/$${BUILD_TYPE}
    OBJECTS_DIR    = $${UNIX_DIR}/obj/$${BUILD_TYPE}
    RCC_DIR        = $${UNIX_DIR}/rcc/$${BUILD_TYPE}
    DESTDIR        = $${BUILD_DIR}/lib/$${BUILD_TYPE}
    DLLDESTDIR     = $${DESTDIR}
}


win32 {
    WIN32_DIR      = $${OUT_PWD}/win32
    MOC_DIR        = $${WIN32_DIR}/moc/$${BUILD_TYPE}
    UI_DIR         = $${WIN32_DIR}/ui/$${BUILD_TYPE}
    UI_HEADERS_DIR = $${WIN32_DIR}/ui/$${BUILD_TYPE}
    UI_SOURCES_DIR = $${WIN32_DIR}/ui/$${BUILD_TYPE}
    OBJECTS_DIR    = $${WIN32_DIR}/obj/$${BUILD_TYPE}
    RCC_DIR        = $${WIN32_DIR}/rcc/$${BUILD_TYPE}
    DESTDIR        = $${BUILD_DIR}/lib/$${BUILD_TYPE}
    DLLDESTDIR     = $${DESTDIR}
}

INSTALLS = target