mirror of
https://github.com/python-LimeReport/LimeReport.git
synced 2024-12-23 20:22:58 +03:00
76 lines
1.6 KiB
Prolog
76 lines
1.6 KiB
Prolog
include(../common.pri)
|
|
QT += core gui
|
|
|
|
CONFIG(release, debug|release) {
|
|
TARGET = LRDemo_r2
|
|
} else {
|
|
TARGET = LRDemo_r2d
|
|
}
|
|
|
|
TEMPLATE = app
|
|
|
|
SOURCES += main.cpp \
|
|
mainwindow.cpp
|
|
|
|
HEADERS += mainwindow.h
|
|
|
|
FORMS += mainwindow.ui
|
|
|
|
INCLUDEPATH += $$PWD/../include
|
|
DEPENDPATH += $$PWD/../include
|
|
|
|
RESOURCES += \
|
|
demo_r2.qrc
|
|
|
|
|
|
EXTRA_DIR += $$PWD/demo_reports
|
|
DEST_DIR = $${DEST_BINS}
|
|
REPORTS_DIR = $${DEST_DIR}
|
|
|
|
macx{
|
|
CONFIG += app_bundle
|
|
}
|
|
|
|
unix:{
|
|
DESTDIR = $$DEST_DIR
|
|
QMAKE_POST_LINK += $$QMAKE_COPY_DIR \"$$EXTRA_DIR\" \"$$REPORTS_DIR\" $$escape_expand(\n\t)
|
|
linux{
|
|
#Link share lib to ../lib rpath
|
|
QMAKE_LFLAGS += -Wl,--rpath=\\\$\$ORIGIN
|
|
QMAKE_LFLAGS += -Wl,--rpath=\\\$\$ORIGIN/lib
|
|
QMAKE_LFLAGS += -Wl,--rpath=\\\$\$ORIGIN/../lib
|
|
QMAKE_LFLAGS_RPATH += #. .. ./libs
|
|
}
|
|
target.path = $${DEST_DIR}
|
|
INSTALLS = target
|
|
}
|
|
|
|
win32 {
|
|
DESTDIR = $$DEST_DIR
|
|
contains(QMAKE_HOST.os, Linux) {
|
|
QMAKE_POST_LINK += $$QMAKE_COPY_DIR \"$$EXTRA_DIR\" \"$$REPORTS_DIR\" $$escape_expand(\n\t)
|
|
} else {
|
|
EXTRA_DIR ~= s,/,\\,g
|
|
DEST_DIR ~= s,/,\\,g
|
|
REPORTS_DIR ~= s,/,\\,g
|
|
RC_FILE += mainicon.rc
|
|
QMAKE_POST_LINK += $$QMAKE_COPY_DIR \"$$EXTRA_DIR\" \"$$REPORTS_DIR\\demo_reports\" $$escape_expand(\\n\\t)
|
|
}
|
|
}
|
|
|
|
LIBS += -L$${DEST_LIBS}
|
|
CONFIG(debug, debug|release) {
|
|
LIBS += -llimereportd
|
|
} else {
|
|
LIBS += -llimereport
|
|
}
|
|
|
|
!CONFIG(static_build) : CONFIG(zint) {
|
|
LIBS += -L$${DEST_LIBS}
|
|
CONFIG(debug, debug|release) {
|
|
LIBS += -lQtZintd
|
|
} else {
|
|
LIBS += -lQtZint
|
|
}
|
|
}
|